Property Let と Set

2026年5月8日にメンテナンス済み

VBA でクラスを作成し、プロパティ(メンバー変数) を取り扱う際に作成する Property メソッドには Get, Set, Let があります。

一般的に、VBA 以外の言語では、プロパティ(メンバー変数)に設定するのは Getter と Setter のみです。

そのため、VBA でのプロパティの定義を初めて見た時違和感を覚える方もいらっしゃるかと思います。

今回は VBA の Property Set と Property Let の違いについてまとめます。

Property Set と Property Let の違い

結論を言ってしまうと、

変数の代入時に Set が必要なものは Set
それ以外は Let

この認識で問題ないかと思います。

解説

参照型の変数に値を代入する際は、Set を付けないとエラーとなります。

ワークシートで言えば、

Dim ws As Worksheet
Set ws = ThisWorkbook.Worksheets(1)

といった場合です。

これはクラスにおける Property でも、同様のことが言えます。

クラスのプロパティに値をセットしたいとき、

' Class1 モジュール

Private m_ws As Worksheet

' Worksheetクラスは参照型なので、Setで定義
Public Property Set ws(ByRef received As Worksheet)

    ' プロパティに設定する場合もSetが必要
    Set m_ws = received
End Property

' 標準モジュール

Dim c1 As Class1
Set c1 = New Class1

' 呼び出した先でもSetが必要
Set c1.ws = ThisWorkbook.Worksheets(1)

一つでも Set がないとエラーとなってしまいます。

とても面倒ですが、**VBA では変数定義時の Set の概念が、Property にも適用されている。**と理解していただいて差支えないかと思います。

実行テスト

' Class1 モジュール
Private m_ws As Worksheet

Public Property Set ws(ByRef received As Worksheet)
    Set m_ws = received
End Property

Public Property Get ws() As Worksheet
    Set ws = m_ws
End Property

' 標準モジュール

Public Sub test()

    Dim c1 As Class1
    Set c1 = New Class1

    Set c1.ws = ThisWorkbook.Worksheets(1)

    Debug.Print c1.ws.Cells(1, 1).Value
End Sub

イミディエイトウィンドウにブックの最初のシートの先頭セルの値が表示されます。

Let で Set を代用しない

オブジェクト参照を受け取るプロパティでは、Property Set を使うのが基本です。Microsoft の VBA リファレンスでも、Property Set はオブジェクトへの参照を設定するプロシージャ、Property Let は値を設定するプロシージャとして説明されています。

値型とオブジェクト型を混在して扱う Variant のような特殊な設計を除けば、実務では次のように使い分けると読み手に意図が伝わりやすくなります。

プロパティの種類	使うプロシージャ	例
文字列、数値、日付、真偽値	`Property Let`	`Name As String`, `Amount As Long`
`Worksheet` や `Range` などのオブジェクト参照	`Property Set`	`TargetSheet As Worksheet`