आम तौर पर त्रुटि हैंडलिंग प्रत्येक फ़ंक्शन में न्यूनतम रूप से की जाती है, और फिर इसे कॉलिंग फ़ंक्शन में थ्रो किया जाता है, लेकिन VBA में इसे आसानी से लागू नहीं किया जा सकता है।
यदि आप एक त्रुटि हैंडलर बनाते हैं, तो उस प्रक्रिया (procedure) में त्रुटि को संभाली हुई माना जाता है और वह कॉलर तक नहीं पहुँचती। सफ़ाई का काम करने के बाद भी कॉलर को सूचित करने के लिए, आपको हैंडलर के भीतर Err.Raise से त्रुटि को दोबारा उठाना होगा।
एक विशिष्ट उदाहरण के रूप में,
- Open फ़ंक्शन के बाद फ़ाइल खोलने पर त्रुटि होने पर भी Close को निष्पादित करना चाहते हैं।
- इसके अलावा, त्रुटि को कॉलिंग फ़ंक्शन में पास करना चाहते हैं।
errNumber = Err.Number
errDescription = Err.Description
On Error GoTo 0
Call Err.Raise(errNumber, , errDescription)
समाधान के लिए उपरोक्त जैसे कोड का उपयोग करें। व्याख्या और उदाहरण नीचे दिए गए हैं।
On Error GoTo 0 और त्रुटि की जानकारी सहेजना
On Error GoTo 0 प्रक्रिया में सक्रिय On Error सेटिंग को अक्षम कर देता है। हैंडलर के अंदर इसका उपयोग करने पर, बाद की त्रुटियाँ इस प्रक्रिया में नहीं संभाली जातीं और कॉलर को भेज दी जाती हैं।
ध्यान दें कि त्रुटि हैंडलर चलने के दौरान Err.Raise से नई त्रुटि उठाने पर भी वह उसी हैंडलर में वापस नहीं जाती, बल्कि कॉलर को चली जाती है। यहाँ On Error GoTo 0 का मूल्य यह है कि यह कोड में स्पष्ट करता है कि यह प्रक्रिया अब त्रुटियाँ नहीं संभालती।
Err ऑब्जेक्ट की सामग्री बाद की प्रक्रियाओं (जैसे On Error स्टेटमेंट (On Error GoTo 0 सहित), Resume या Exit Sub) से ओवरराइट या साफ़ हो सकती है। इसलिए हैंडलर की शुरुआत में Err.Number और Err.Description को वेरिएबल में सहेज लेना सबसे सुरक्षित है। विवरण को Err.Raise में देने पर कॉलर भी मूल त्रुटि संदेश देख सकता है।
प्रवाह इस प्रकार है:
- त्रुटि होती है और निष्पादन त्रुटि हैंडलर पर जाता है।
- त्रुटि की जानकारी वेरिएबल में सहेजें।
On Error GoTo 0से हैंडलर रद्द करें।- सफ़ाई का काम (जैसे Close) करें।
Err.Raiseसे त्रुटि को कॉलर तक पहुँचाएँ।
इससे आप अन्य प्रोग्रामिंग भाषाओं में catch के भीतर throw करने वाले Try-Catch-Finally की तरह कार्यान्वयन कर सकते हैं।
कोड उदाहरण
केवल त्रुटि हैंडलिंग → थ्रो की आवश्यकता हो
Public sub Caller()
On Error GoTo ERROR_HANDLER
Call Called
ERROR_HANDLER:
Debug.Print(Err.Number)
End Sub
Public sub Called()
On Error GoTo ERROR_HANDLER
Dim errNumber as Long
' त्रुटि उत्पन्न करने वाली प्रक्रिया लिखें
Exit Sub
ERROR_HANDLER:
errNumber = Err.Number
On Error GoTo 0
' यहाँ त्रुटि के बाद की प्रक्रिया लिखें
' त्रुटि को कॉलिंग फ़ंक्शन में पास करें
Call Err.Raise(errNumber)
End Sub
Try-Catch-Finally का कार्यान्वयन
यह काफी लंबा कोड है।
Public sub Caller()
On Error GoTo ERROR_HANDLER
Call Called
ERROR_HANDLER:
Debug.Print(Err.Number)
End Sub
Public sub Called()
On Error GoTo ERROR_HANDLER
Dim errNumber as Long
' त्रुटि उत्पन्न करने वाली प्रक्रिया लिखें
FINALLY:
If errNumber <> 0 then
Call Err.Raise(errNumber)
End if
Exit Sub
ERROR_HANDLER:
errNumber = Err.Number
On Error GoTo 0
' यहाँ त्रुटि के बाद की प्रक्रिया लिखें
Resume FINALLY
End Sub
वास्तविक उदाहरण
केवल Try-Catch का उपयोग
'------------------------------------------------
'
' फ़ंक्शन को कॉल करने वाला फ़ंक्शन
'
'------------------------------------------------
Public Sub Caller()
On Error GoTo ERROR_HANDLER
Call Called
ERROR_HANDLER:
Debug.Print "कॉलिंग फ़ंक्शन : Catch"
End Sub
'------------------------------------------------
'
' कॉल किया गया (थ्रो करने वाला) फ़ंक्शन
'
'------------------------------------------------
Public Sub Called()
On Error GoTo ERROR_HANDLER
Dim errNumber as Long
Dim n As Long: n = 1 / 0
Exit Sub
ERROR_HANDLER:
errNumber = Err.Number
On Error GoTo 0
Debug.Print "कॉल किया गया फ़ंक्शन : Catch"
' त्रुटि को कॉलिंग फ़ंक्शन में पास करें
Call Err.Raise(errNumber)
End Sub
निष्पादन परिणाम
कॉल किया गया फ़ंक्शन : Catch
कॉलिंग फ़ंक्शन : Catch
Try-Catch-Finally का कार्यान्वयन
'------------------------------------------------
'
' फ़ंक्शन को कॉल करने वाला फ़ंक्शन
'
'------------------------------------------------
Public sub Caller()
On Error GoTo ERROR_HANDLER
Call Called
ERROR_HANDLER:
Debug.Print "कॉलिंग फ़ंक्शन : Catch"
End Sub
'------------------------------------------------
'
' कॉल किया गया (थ्रो करने वाला) फ़ंक्शन
'
'------------------------------------------------
Public sub Called()
On Error GoTo ERROR_HANDLER
Dim errNumber as long
Dim n as long: n = 1 / 0
FINALLY:
Debug.Print "कॉल किया गया फ़ंक्शन : Finally"
If errNumber <> 0 then
Call Err.Raise(errNumber)
End if
Exit Sub
ERROR_HANDLER:
errNumber = Err.Number
On Error GoTo 0
Debug.Print "कॉल किया गया फ़ंक्शन : Catch"
Resume FINALLY
End Sub
निष्पादन परिणाम
कॉल किया गया फ़ंक्शन : Catch
कॉल किया गया फ़ंक्शन : Finally
कॉलिंग फ़ंक्शन : Catch