vba · DOCS

Codificación a Base64

Actualizado el

Base64 es uno de los métodos de codificación y representa los datos con 64 caracteres.

Todavía se usa principalmente en correos electrónicos, software y API web.

En esta página presentamos cómo convertir datos de texto a Base64 usando VBA. El código usa enlace tardío con CreateObject, por lo que no requiere configurar referencias.

Precaución

El código usa ADODB.Stream y MSXML, componentes COM de Windows. No funciona en Excel para Mac.

Precaución

Este ejemplo convierte el texto con us-ascii, por lo que solo admite cadenas ASCII como caracteres alfanuméricos. Los caracteres multibyte (por ejemplo, japonés) se convierten en ? antes de codificarse. Para ese caso, consulte “Texto no ASCII (UTF-8)” más abajo.

Código fuente

'*-------------------------------------------------------------
'* Codificar texto en Base64
'*
'* @param text Valor de conversión
'* @return Datos en formato Base64
'*-------------------------------------------------------------
Public Function EncodeToBase64(ByRef text As String) As String

  ' Preparación del objeto
  Dim node As Object
  Set node = CreateObject("Msxml2.DOMDocument.3.0").createElement("base64")

  ' Codificación
  node.DataType = "bin.base64"
  node.nodeTypedValue = ConvertToBinary(text)

  ' Eliminar saltos de línea que no se pueden eliminar con la función y devolver
  EncodeToBase64 = Replace(node.text, vbLf, "")
End Function

'*-------------------------------------------------------------
'* Convertir cadena a datos binarios
'*
'* @param text Valor de conversión
'* @return Datos binarios
'*-------------------------------------------------------------
Public Function ConvertToBinary(ByRef text As String)

  ' Preparación del objeto
  Dim BinaryStream As Object
  Set BinaryStream = CreateObject("ADODB.Stream")

  ' Configuración del Stream
  With BinaryStream
    .Type = 2
    .Charset = "us-ascii"
    .Open
    .WriteText text
    .Position = 0
    .Type = 1
    .Position = 0
  End With

  ConvertToBinary = BinaryStream.Read
End Function

Prueba de ejecución

Ejecución

Public Sub execute()
    Debug.Print (EncodeToBase64("aaa"))
    Debug.Print (EncodeToBase64("aab"))
    Debug.Print (EncodeToBase64("aac"))
End Sub

Resultados

YWFh
YWFi
YWFj

Texto no ASCII (UTF-8)

La mayoría de las API web esperan el Base64 de una secuencia de bytes UTF-8. Si solo cambia el juego de caracteres a utf-8, se antepone un BOM de 3 bytes y el resultado no coincidirá con otros sistemas. Después de cambiar el flujo a binario, establezca Position = 3 para omitir el BOM.

'*-------------------------------------------------------------
'* Convertir cadena a datos binarios UTF-8 (sin BOM)
'*
'* @param text Valor de conversión
'* @return Datos binarios
'*-------------------------------------------------------------
Public Function ConvertToBinaryUtf8(ByRef text As String)

  If Len(text) = 0 Then Exit Function

  Dim BinaryStream As Object
  Set BinaryStream = CreateObject("ADODB.Stream")

  With BinaryStream
    .Type = 2
    .Charset = "utf-8"
    .Open
    .WriteText text
    .Position = 0
    .Type = 1
    ' Omitir el BOM (3 bytes)
    .Position = 3
  End With

  ConvertToBinaryUtf8 = BinaryStream.Read
End Function

Si reemplaza ConvertToBinary(text) por ConvertToBinaryUtf8(text) en EncodeToBase64, "あ" se convierte en 44GC (el Base64 de los bytes UTF-8 E3 81 82).

Conversión a Base64URL

Base64URL, usado en JWT y URL, se diferencia del Base64 estándar en lo siguiente:

  • Se reemplaza + por - y / por _
  • Se omite el relleno final =
Public Function ToBase64Url(ByVal base64 As String) As String
  base64 = Replace(base64, "+", "-")
  base64 = Replace(base64, "/", "_")
  ToBase64Url = Replace(base64, "=", "")
End Function

Funcionamiento y precauciones

  • Base64 divide 3 bytes (24 bits) en cuatro grupos de 6 bits, por lo que el tamaño de los datos aumenta aproximadamente 4/3.
  • Si el número de bytes no es múltiplo de 3, el final se rellena con = (por ejemplo, "a" → YQ==).
  • Base64 es una codificación, no un cifrado. Codificar una contraseña en Base64 no la protege.
  • La salida Base64 de MSXML incluye un salto de línea cada 76 caracteres, por eso el ejemplo elimina vbLf.

Información adicional sobre Base64

Base64 es un método de codificación que utiliza solo 64 caracteres imprimibles para manejar datos multibyte y binarios en entornos de comunicación que no pueden manejar otros caracteres. Está especificado por MIME y se utiliza ampliamente en correos electrónicos que solo pueden manejar datos de 7 bits. Específicamente, utiliza 62 caracteres de A–Z, a–z, 0–9, dos símbolos (+, /) y el símbolo = para el relleno.

Base64 - Wikipedia

Como se menciona en la cita anterior, Base64 todavía se usa ampliamente, y también existen Base16, Base32, entre otros.

Dado que está especificado por MIME, se utilizará en VBA cuando el tipo MIME de la API especifique Base64.

  • #Excel
  • #VBA